【第450回】 Marketing Cloud Next ： API を使ってフローから離脱させる方法

2026年2月10日 09:17

Marketing Cloud Next Growth & Advanced Edition では、セグメントトリガーフロー、イベントトリガーフロー、オンデマンドフロー など、さまざまなフローを使ってリアルタイム施策や自動化を実現できます。

しかし運用していると、こんなケースはありませんか？

✅ 購入完了したのにリマインドメールが送られ続ける
✅ すでに対応済みなのにフォローアップが止まらない
✅ 外部システム側で処理完了したためフローを終了したい

このような 「もうフローに残す必要がない個人」 を動的に離脱させるための仕組みが、Spring '26 の新機能リリースで登場した Exit Individuals from a Flow Action（REST API）です。

この API を使うと、
実行中のフローから特定の個人（Individual）を即座に退出させる
ことができます。

ユースケース例

🛒 購入リマインドフロー

カート放棄
1 日後リマインド
3 日後再通知
7 日後クーポン送付

途中で、外部 EC サイトで購入完了

このままだと
❌ 「まだ購入していませんか？」メールが送られる
⇒ そこで、Exit Individuals API でフローから離脱させる

対応フロータイプ

このアクションは、以下のフローで利用可能です。

セグメントトリガーフロー
イベントトリガーフロー
オンデマンドフロー

API仕様

この API は「API version 66.0」（Spring '26）以降で動きます。

--- メソッド 
POST 

--- エンドポイント
https://[私のドメイン名].my.salesforce.com/services/data/v66.0/actions/custom/exitIndividualsFromFlow/flow_API_name

--- ヘッダー 
Content-Type：application/json 
Authorization：Bearer [アクセストークン] 

--- ボディ
{
  "inputs": [
    {
      "individualId": "003R000000ExAmPlE",
      "flowVersionId": "301R000000AbCdEfG",
      "description": "Customer completed purchase via external portal."
    }
  ]
}

フローバージョン（flowVersionId）は任意です。指定がない場合は、すべてのバージョンから退出します。
説明（description）も任意です。

実装イメージ（活用パターン）

パターン①：外部EC完了トリガー

EC → Webhook → Lambda → REST API → Exit Flow

パターン②：CRM更新トリガー

Opportunity Closed Won → Apex → Callout → Exit Flow

パターン③：サポート完了

Case Closed → Event-Triggered Flow → Exit Flow

取引先責任者のページに強制退出画面を作る

最後に、画面フローを作成して連絡先の退出画面を作成してみます。
具体的には、以下のような流れになります。

Contact レコード
↓（クイックアクション）
Screen Flow
↓
Contact → IndividualId 取得
↓
Flow API 名を手入力
↓
Apex（Invocable）
↓
POST /actions/custom/exitIndividualsFromFlow/{flowApiName}

設定手順

1. Named Credential の作成

この作成方法については、以下の 2 つの記事をご確認ください。

以下の記事で「コンシューマー鍵」と「コンシューマーの秘密」を取得するところまで進めてください。

上で取得した「コンシューマー鍵」と「コンシューマーの秘密」を使って、Named Credential（指定ログイン情報）を作成してください。
「データグラフのスケジュール実行」セクションの手順 1 ～ 24 を実行してください。下の Apex をそのまま利用する場合は、Named Credential の Name（API 名）を「SelfOrg」と命名してください。

2. Apex クラスを登録

以下を登録してください。
設定で登録されている Named Credential（指定ログイン情報）の Name（API 名）が「SelfOrg」であるか、再度確認してください。

public with sharing class ExitIndividualsFromFlowAction {

    public class Request {
        @InvocableVariable(required=true)
        public String individualId;

        @InvocableVariable(required=true)
        public String flowApiName;
    }

    public class Result {
        @InvocableVariable public Boolean success;
        @InvocableVariable public Integer statusCode;
        @InvocableVariable public String message;
        @InvocableVariable public String responseBody;
    }

    @InvocableMethod(label='Exit Individual From Flow')
    public static List<Result> run(List<Request> requests) {

        List<Result> results = new List<Result>();

        for (Request req : requests) {
            Result r = new Result();

            try {
                String apiName = (req.flowApiName == null) ? '' : req.flowApiName.trim();

                HttpRequest httpReq = new HttpRequest();
                httpReq.setMethod('POST');
                httpReq.setEndpoint(
                    'callout:SelfOrg/services/data/v66.0/actions/custom/exitIndividualsFromFlow/' +
                    EncodingUtil.urlEncode(apiName, 'UTF-8')
                );
                httpReq.setHeader('Content-Type', 'application/json');
                httpReq.setTimeout(120000);

                Map<String,Object> body = new Map<String,Object>{
                    'inputs' => new List<Object>{
                        new Map<String,Object>{ 'individualId' => req.individualId }
                    }
                };
                httpReq.setBody(JSON.serialize(body));

                HttpResponse res = new Http().send(httpReq);

                r.statusCode = res.getStatusCode();
                r.responseBody = res.getBody();
                r.success = (r.statusCode >= 200 && r.statusCode < 300);

                if (r.success) {
                    r.message = 'Successfully exited';
                } else {
                    r.message = r.responseBody;

                    if (r.statusCode == 400 && !String.isBlank(r.responseBody)) {
                        String errCode = extractFirstErrorStatusCode(r.responseBody);

                        if (errCode == 'INDIVIDUAL_NOT_IN_FLOW') {
                            r.message = 'This individual is not currently in the flow (no exit required)';
                        }
                    }
                }

            } catch (Exception e) {
                r.success = false;
                r.message = 'Exception: ' + e.getMessage();
            }

            results.add(r);
        }

        return results;
    }

    private static String extractFirstErrorStatusCode(String jsonText) {
        try {
            Object root = JSON.deserializeUntyped(jsonText);

            if (!(root instanceof List<Object>)) return null;
            List<Object> rootList = (List<Object>)root;
            if (rootList.isEmpty()) return null;

            Object first = rootList[0];
            if (!(first instanceof Map<String,Object>)) return null;
            Map<String,Object> firstMap = (Map<String,Object>)first;

            Object errorsObj = firstMap.get('errors');
            if (!(errorsObj instanceof List<Object>)) return null;
            List<Object> errors = (List<Object>)errorsObj;
            if (errors.isEmpty()) return null;

            Object e0 = errors[0];
            if (!(e0 instanceof Map<String,Object>)) return null;
            Map<String,Object> e0Map = (Map<String,Object>)e0;

            Object statusCodeObj = e0Map.get('statusCode');
            return (statusCodeObj == null) ? null : String.valueOf(statusCodeObj);

        } catch (Exception ignore) {
            return null;
        }
    }
}