25年8月版：ComfyUIをメンテナンスするためのバッチファイル群

Last update 11-30-2025
※ (11-30-2025) 「ComfyUIのアップデート（2-2.）」のバッチファイルを差し替えました。「git checkout master」を追加しています。
※ (11-16-2025) PyTorchのアップデートに対応するため、「PyTorchのインストール・アップデート、アンインストール（2-3.）」「ComfyUIのインストール（5-2.）」のバッチファイルを差し替えました。
※ (11-16-2025) 「ComfyUIの起動（5-3.）」のバッチファイルを差し替えました。
※ 日常の多くのメンテナンスはComfyUI Managerにて対応できます。本記事のバッチファイルは必ずしも必要ではありません。
※ 現在のところ、ポータブル版のComfyUIには対応していません。ご了承ください。
※ 関連記事は、ComfyUIの記事一覧にまとめてあります。

■ 0. 概要

▼ 0-0. はじめに

　本記事では、筆者が制作したComfyUI用の各種バッチファイルについて説明しています。ComfyUIを新規インストールする記事の続きとも言えます。

　2.以降にて、メンテナンス等で用いるバッチファイルを掲載していますので、気に入ったものがあればダウンロードして自由にご利用ください。なお、ポータブル版には対応していませんのでご注意ください。

　ソースの一部は生成AIを利用していますが、内容は筆者が確認して全体的に手を入れています。

▼ 0-1. バッチファイルの目次

　本記事で説明しているバッチファイルの一覧です。

■ 初期の基本セット → 1.へ

• ComfyUIのインストール

• ComfyUIの起動

• ComfyUI Managerのインストール

■ メンテナンス用のセット → 2.へ

• ComfyUIのアップデート → 2-2.

• PyTorchのインストール・アップデート、アンインストール → 2-3.

• パッケージのインストール・アップデート → 2-4.

■ その他 のバッチファイル→ 3.へ

• 仮想環境の手動操作 → 3-2.

• パッケージの状態を記録 → 3-3.

• 仮想環境の新規作成 → 3-4.

■ 補足→ 4.へ

• Pythonのキャッシュの削除 → 4-2.

• HuggingFaceモデルのキャッシュの削除 → 4-3.

• PyTorchの再インストール → 4-4.

■ 初期の基本セットのソース→ 5.へ

• ComfyUIのインストール

• ComfyUIの起動

• ComfyUI Managerのインストール

　現時点では以上となります。状況に応じて、項目の追加や内容の変更等を行う場合があります。

▼ 0-2. TIPS

　バッチファイルはすべて、ComfyUIのインストール先の一つ上のフォルダに設置する設計となっています。バッチファイルが多くて邪魔に感じられる場合は、下記のいずれかの方法で対応が可能です。

• 元々の設置場所に別のフォルダを作成して、バッチファイルをその中に移動します。移動したファイルを編集して、「cd /d %~dp0」の次の行に「cd ..」を追加します。

• バッチファイルを任意のフォルダに移動します。移動したファイルを編集し、「cd /d %~dp0」の代わりに「cd /d c:\aiwork」のように、元々の設置場所を直接指定します。

▼ 0-3. 補足

　ComfyUIに関するすべての記事は、下記にまとめてあります。

■ 1. 初期の基本セット

▼ 1-1. 説明

　ComfyUIを新規インストールする際に必要となる最小限のバッチファイルは、下記の記事に掲載しています。

• ComfyUIのインストール → 3-3.へ

• ComfyUIの起動 → 3-5.へ

• ComfyUI Managerのインストール → 4-2.へ

　それぞれのソースは、本記事の5.に掲載しています。

　ComfyUI自身に関わるパッケージの更新頻度が高いため、「ComfyUIの起動」のバッチファイルにアップデート処理を含めています。

　バッチファイルの設置場所は、ComfyUIのインストール先の一つ上のフォルダです。ポータブル版には対応していません。

■ 2. メンテナンス用のセット1

▼ 2-1. 説明

　本項では下記のバッチファイルを説明しています。なお、現在においてはComfyUI Manager上で日常的なメンテナンスが可能になっているため、必ずしも下記のバッチファイルが必要ではない点を付け加えておきます。

• ComfyUIのアップデート → 2-2.

• PyTorchのインストール・アップデート → 2-3.

• パッケージのインストール・アップデート → 2-4.

　バッチファイルの設置場所は、ComfyUIをインストールしたフォルダの一つ上のフォルダです。ポータブル版には対応していません。

　日常ではときどき、または必要時に2-2.のバッチファイルでComfyUI本体をアップデートします。

　2-3.や2-4.のバッチファイルを使う機会は少ないです。ただし、問題が発生したときに役に立つ場合があります。

▼ 2-2. ComfyUIのアップデート

　ComfyUI本体をアップデートし、構成ファイルを最新の状態にします。ComfyUI Managerの「Update ComfyUI」で同じ処理ができるため、起動していない状態でアップデートしたい場合に利用します。

　処理内容としては、「git checkout master」と「git pull」のコマンドを順に実行しています。

（Last update 11-30-2025）

　下記はファイルの内容です。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo "git checkout master" と "git pull" のコマンドを使用して、ComfyUI の構成ファイルをアップデートします．
echo.

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
pause

@echo on
git checkout master
git pull
@echo off
echo.

echo ** message **
echo "git pull" の処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 2-3. PyTorchのインストール・アップデート、アンインストール

　ComfyUIの仮想環境に、PyTorchをインストールまたはアップデートするバッチファイルと、アンインストールするバッチファイルを用意しました。

◆ CUDA 13.0用

　こちらのバッチファイルでインストールを行う前に、次に掲載しているアンインストール用のバッチファイルを実行してください。

（Last update 11-16-2025）

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo "pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130" のコマンドを実行します。
echo.
echo ComfyUI の仮想環境にて、PyTorch のインストールまたはアップデートを行います．
echo PyTorch は 【Stable版（CUDA 13.0）】をインストールします．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
echo.
echo ** PyTorch のインストール **
@echo on
pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130
@echo off
echo.

echo ** message **
echo "pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130" の処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

◆ PyTorchのアンインストール

　PyTorchのアンインストールを行うためのバッチファイルも用意しました。こちらを実行した後、インストールも行ってください。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo "pip uninstall -y torch torchvision torchaudio のコマンドを実行します。
echo.
echo ComfyUI の仮想環境にて、PyTorch のアンインストールを行います．
echo アンインストールが完了したら、改めて必要な PyTorch のインストールを行ってください．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
echo.
echo ** PyTorch のアンインストール **
@echo on
pip uninstall -y torch torchvision torchaudio
@echo off
echo.

echo ** message **
echo "pip uninstall -y torch torchvision torchaudio" の処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 2-4. パッケージのインストール・アップデート

　ComfyUIの仮想環境に、ComfyUI本体が必要とするパッケージをインストールまたはアップデートします。念のため、ComfyUI Manager がインストールされている場合はそちらも処理します。

　処理内容としては、仮想環境内で「pip install -r requirements.txt」のコマンドを実行しています。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo "pip install -r requirements.txt" のコマンドを実行します。
echo.
echo ComfyUI の仮想環境にて、必要なパッケージのインストールまたはアップデートを行います．
echo ComfyUI Manager がインストールされている場合、そちらも同様に処理します．
echo 仮想環境に PyTorch がインストールされていない場合、CPU 版の PyTorch がインストールされるので注意してください．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
echo.
echo ** パッケージのインストール **
@echo on
pip install -r requirements.txt
@echo off
echo.

echo ** message **
echo "pip install -r requirements.txt" の処理が終わりました．
echo.

if not exist ".\custom_nodes\ComfyUI-Manager\requirements.txt" (
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF
)

echo ** message **
echo 続いて、ComfyUI Manager に必要なパッケージのインストールを行います．
echo.
pause

echo.
echo ** パッケージのインストール **
@echo on
pip install -r .\custom_nodes\ComfyUI-Manager\requirements.txt
@echo off
echo.

echo ** message **
echo "pip install -r .\custom_nodes\ComfyUI-Manager\requirements.txt" の処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

■ 3. メンテナンス用のセット2

▼ 3-1. 説明

　本項では下記のバッチファイルを掲載しています。

• 仮想環境の手動操作 → 3-2.

• インストール済みパッケージの記録 → 3-3.

• 仮想環境の新規作成 → 3-4.

• 任意のパッケージをファイルからインストール → 3-5.

　バッチファイルの設置場所は、ComfyUIのインストール先の一つ上のフォルダです。ポータブル版には対応していません。

▼ 3-2. 仮想環境の手動操作

　ComfyUIの仮想環境を有効化した状態で、コマンドプロンプトが利用できます。こちらの扱いは慎重に行ってください。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のコマンドが実行できます。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境を有効にしました．引き続き、任意のコマンドが実行できます．
echo こちらはエキスパート向けです。仮想環境の扱いは慎重に行ってください．
echo.

cmd /k
exit

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 3-3. インストール済みパッケージの記録

　ComfyUIの仮想環境を有効化した状態で「pip freeze」コマンドを実行して、その内容を実行した日時のファイル名（pip-freeze(ComfyUI)_20250819-001122.txt 等）で保存します。

@echo off
setlocal enabledelayedexpansion
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境にインストールされているパッケージの一覧を、テキストファイルに保存します。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

call .\ComfyUI\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

for /f "usebackq tokens=*" %%i in (`powershell -Command "Get-Date -Format 'yyyyMMdd-HHmmss'"`) do set DateTime=%%i
set FileName=pip-freeze(ComfyUI)_!DateTime!.txt
pip freeze > "!FileName!"

echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境を有効にして、インストールされているパッケージの一覧を保存します．
echo.
echo ** message **
echo !FileName! にパッケージの一覧を出力しました．
echo バッチファイルの実行を終了します．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 3-4. 仮想環境の新規作成

　ComfyUIの仮想環境を新規に作成します。ComfyUIがどうやっても起動できなくなった場合や、仮想環境を作り直したい場合に使用します。

　ComfyUIのインストールフォルダにvenvフォルダがある場合は処理を中止しますので、現状の仮想環境を残しておきたい場合はリネームして、不要な場合は削除してください。

　仮想環境の作成しか行いませんので、これを行った後に2-3.の「PyTorchのインストール」と2-4.の「パッケージのインストール」のバッチファイルを続けて実行します。

　ComfyUIの構成ファイルに異常が無ければ、これで起動できるようになります。ただし、多くの拡張機能がそのままでは利用できなくなるので、個別に対応が必要です。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo .\ComfyUI\ のフォルダに仮想環境を新規作成します。
echo.
echo 作成後は必要に応じて、PyTorch やその他のパッケージのインストール等を行ってください．
echo 新しい仮想環境で ComfyUI の拡張機能が動作しなくなった場合は、個別に対応する必要があります．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存在しないので、バッチファイルの実行を中止します．"
)

if exist ".\ComfyUI\venv\" (
  call :ErrorExit ".\ComfyUI\venv\ のフォルダが存在するので、バッチファイルの実行を中止します．" "フォルダのリネームまたは削除を行ってください．"
)

cd .\ComfyUI
pause
echo.

echo ** 仮想環境の準備 **
@echo on
python -m venv .\venv
@echo off
call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
@echo on
python -m pip install --upgrade pip
@echo off
echo.

echo ** message **
echo 仮想環境の作成処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 3-5. 任意のパッケージをファイルからインストール

　ComfyUIの仮想環境を有効化した状態で、指定されたwhlファイルをpipコマンドでインストールします。ファイルはバッチファイルへドラッグ＆ドロップします。こちらの扱いは慎重に行ってください。

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のパッケージをインストールできます。
echo.

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo ** このバッチファイルの説明 **
echo ComfyUI の仮想環境を有効にした状態で、任意のパッケージをインストールできます。
echo.

if "%~1"==""  (
  call :ErrorExit "インストールする whl ファイルをドラッグ＆ドロップしてください．バッチファイルの実行を中止します．"
)

if not exist "%~1" (
  call :ErrorExit "指定されたファイル %~1 が見つかりません．バッチファイルの実行を中止します．"
)

if /i not "%~x1"==".whl" (
  call :ErrorExit "指定されたファイル %~1 は whl ファイルではありません．バッチファイルの実行を中止します．"
)

echo ** 確認 **
echo 下記の whl ファイルをインストールします．
echo %~1
echo.
pause

echo.
echo ** パッケージのインストール **
@echo on
pip install "%~1"
@echo off
echo.

echo ** message **
echo "pip install" の処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

■ 4. その他の情報

▼ 4-1. 説明

　バッチファイルでは提供していない処理の手順を説明します。

• Pythonのキャッシュの削除 → 4-2.

• HuggingFaceモデルのキャッシュの削除 → 4-3.

• PyTorchの再インストール → 4-4.

▼ 4-2. Pythonのキャッシュの削除

　Pythonはパッケージのインストールを行った際、ディスク上にパッケージのキャッシュを残します。これを全て削除するコマンドを紹介します。

　操作は "comfy_maintenance4(venv_activate).bat" （仮想環境の手動操作）のバッチファイル経由で行っても、通常のコマンドプロンプト経由で行っても構いません。

pip cache purge

▼ 4-3. HuggingFaceモデルのキャッシュの削除

　ComfyUIの一部の拡張機能では、HuggingFaceのモデルをダウンロードして利用します。モデルの保存場所は拡張機能によって異なり、ComfyUIのmodelsフォルダ内の場合と、そうでない場合があります。

　ダウンロードしたモデルがComfyUI\models内に無い場合は、削除するために一手間かかります。

　操作は "comfy_maintenance4(venv_activate).bat" （仮想環境の手動操作）のバッチファイルから行います。下記のコマンドを実行します。

hf cache scan

　先ほどの「huggingface-cli scan-cache」を実行すると、キャッシュに保存されたモデルや容量の一覧が表示されます。

　モデルを削除したい場合は、下記のコマンドを実行します。カーソルキーの上下とスペースで削除するモデルを選択し、Enterで削除を実行します。Ctrl+Cで終了します。

hf cache delete

　エラーが出てhfコマンドが実行できない場合は、下記のコマンドを実行して必要なパッケージをインストールします。

pip install "huggingface_hub[cli]"

▼ 4-4. PyTorchの再インストール

　2-3.に、PyTorchをアンインストールするバッチファイルと、インストールするバッチファイルを用意しました。その2つを順番に実行してください。

　バッチファイルの設置場所は、ComfyUIのインストール先の一つ上のフォルダです。ポータブル版には対応していません。

■ 5. 初期の基本セットのソース

▼ 5-1. 説明

　1.にて説明だけ行ったバッチファイルのソースです。掲載元の記事に載せると冗長になるため、この記事ができるまで掲載場所が無い状態でした。

バッチファイルの掲載元：25年8月版：ComfyUIを新規インストールする手順（Windows+GeForce）

▼ 5-2. ComfyUIのインストール

　現在のPyTorchはStable版がGeForce RTX 5xxxに対応しているため、Nightly版向けは提供を終了しました。

comfy_install_rtx(cu130-stable).bat （Last update 11-16-2025）

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo ComfyUI をインストールします．
echo.
echo Git と Python が実行できるようになっている必要があります（チェックは行いません）．
echo PyTorch は 【Stable版（CUDA 13.0）】をインストールします．
echo.

if exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ のフォルダが存在するので、バッチファイルの実行を中止します．" "フォルダのリネームまたは削除を行ってください．"
)

echo ** message **
echo はじめに、ComfyUI のダウンロードを行います．
echo.
pause
echo.

echo ** ComfyUI のダウンロード **
@echo on
git clone https://github.com/comfyanonymous/ComfyUI
@echo off
echo.

echo ** message **
echo エラーが出ている場合は内容を確認して、バッチファイルの実行を中止してください．
echo.
echo ** message **
echo 次に、PyTorch のインストールを行います（少しかかります）．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

cd .\ComfyUI
pause
echo.

echo ** 仮想環境の準備 **
@echo on
python -m venv .\venv
@echo off
call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
@echo on
python -m pip install --upgrade pip
@echo off
echo.

echo ** PyTorch のインストール **
@echo on
pip install torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu130
@echo off
echo.

echo ** message **
echo エラーが出ている場合は内容を確認して、バッチファイルの実行を中止してください．
echo 次に、必要なパッケージのインストールを行います（少しかかります）．
echo.
pause
echo.

echo ** パッケージのインストール **
@echo on
pip install -r requirements.txt
@echo off
echo.

echo ** message **
echo ComfyUI のインストール処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

▼ 5-3. ComfyUIの起動

　バッチファイルのソースは掲載元の記事にも記載しています。

comfy.bat (Last update 11-15-2025)

@echo off
cd /d %~dp0

if not exist ".\ComfyUI\" (
  call :ErrorExit ".\ComfyUI\ is not found."
)

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat is not found."
)

cd .\ComfyUI
call venv\Scripts\activate.bat
@echo on
python main.py --auto-launch

goto :END

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2

:END
echo.
pause
exit

▼ 5-4. ComfyUI Managerのインストール

comfy_install_manager.bat (Last update 8-18-2025)

@echo off
rem ** Save this file in Shift_JIS encoding (Japanese-language version) **
cd /d %~dp0

echo ** このバッチファイルの説明 **
echo ComfyUI Manager をインストールします．
echo.
echo ComfyUI のインストールが完了している必要があります（ポータブル版は不可）．
echo この後、画面の表示が消去されますが正常な動作です．
echo.

if not exist ".\ComfyUI\custom_nodes\" (
  call :ErrorExit ".\ComfyUI\custom_nodes\ のフォルダが存在しないので、バッチファイルの実行を中止します．"
)

if exist ".\ComfyUI\custom_nodes\ComfyUI-Manager\" (
  call :ErrorExit ".\ComfyUI\custom_nodes\ComfyUI-Manager\ のフォルダが存在するので、バッチファイルの実行を中止します．"
)

if not exist ".\ComfyUI\venv\Scripts\activate.bat" (
  call :ErrorExit ".\ComfyUI\venv\Scripts\activate.bat のファイルが存在しないので、バッチファイルの実行を中止します．"
)

cd .\ComfyUI
pause
echo.

call .\venv\Scripts\activate.bat
if not defined VIRTUAL_ENV (
  echo.
  call :ErrorExit "仮想環境の有効化に失敗したので、バッチファイルの実行を中止します．"
)

echo.
echo ** message **
echo 仮想環境が有効化されました．
echo.

echo ** ComfyUI Manager のダウンロード **
cd .\custom_nodes
@echo on
git clone https://github.com/Comfy-Org/ComfyUI-Manager
@echo off
echo.

echo ** message **
echo エラーが出ている場合は内容を確認して、バッチファイルの実行を中止してください．
echo 次に、必要なパッケージのインストールを行います．
echo.
pause

echo.
echo ** パッケージのインストール **
@echo on
pip install -r .\ComfyUI-Manager\requirements.txt
@echo off
echo.

echo ** message **
echo ComfyUI Manager のインストール処理が終わりました．
echo.
echo バッチファイルの実行を終了します．
echo エラーが出ている場合は内容を確認してください．
echo.
pause

goto :EOF

:ErrorExit
echo ** ERROR **
echo %~1
if not "%~2"=="" echo %~2
echo.
pause

exit

■ 6. 表紙について

　現在の表紙は、Qwen-Imageで作成した画像をQwen-Image-Editで編集したものです。それぞれ下記の記事と同じものを利用しています。

• （画像）
  ComfyUIでFP8/GGUF版のQwen-Imageを試す（要VRAM 12～16GB）
  https://note.com/mayu_hiraizumi/n/n5686098c2746 

• （ワークフロー）
  ComfyUIでQwen-Image-Editを試す（FP8版、Lightning使用）
  https://note.com/mayu_hiraizumi/n/n4b57fc521932 

• （ワークフローのプロンプト）
  change anime style like chibi style, bold lines

■ 7. その他

　私が書いた他の記事は、メニューよりたどってください。

　ComfyUIに限定した記事の一覧もあります。

　記事に関することで何かありましたら、Xの@riddi0908までお願いします。