shader入门精要读书笔记39 卡通风格的渲染

一、前言

实现卡通渲染有很多方法，其中之一就是基于色调的着色技术。

在实际实现中，我们通常使用漫发射系数对一张一维纹理进行采样，以控制漫反射的色调。

除了光照外，卡通风格渲染通常也要在物体边缘绘制轮廓，这里会使用基于模型的描边方法。

二、渲染轮廓线

P288有5中方法的简述

最后一种就是混合前面四种，

首先找到精确的轮廓线，将模型和轮廓渲染到纹理中，再用图像识别的方法识别轮廓线，再在图像空间下进行风格化渲染。

本节使用的是几何轮廓线渲染的方法对模型进行描边，
将会使用两个Pass， 第一个Pass我们会使用轮廓线颜色渲染整个背面的面片，并在视角空间下把模型顶点沿着法线方向扩张一段距离，来让背部轮廓可见。
我们会让法线的z轴缩小，使其处于一个定值，然后在使用法线方向，这样我们会让背面扁平化，防止其遮挡正面。

viewNormal.z = -0.5;
viewNormal = normallize(viewNormal);
viewPos = ViewPos + viewNormal * _Outline;

三、添加高光

卡通风格的高光通常会在模型上形成一块块分界明显的纯色区域。

之前的Blinn-Phong模型：

fixed3 halfDir = normalize(worldLightDir+viewDir);//计算Blinn-Phong中的h。
fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(max(0，dot(worldNormal,halfDir)),_Gloss);
//计算高光反射部分(Blinn-Phong)

卡通模型的高光效果仍然需要这样计算，只不过就是需要进行判断我们把结果只和一个阙值进行比较，如果小于该阙值，返回高光系数为0，否则返回1。

//两个函数
//step
spec = step(a, b);	//a是参考值，b是待比较值，b>=a时 返回1，
//smoothstep
spec = smoothstep(-w，w，spec-threshold);//这个判断spec-threshold与-w，w的的大小关系
//如果<-w，返回0，大于w，返回1，否则在0，1之间进行插值。

我们需要在高光区域边界消除锯齿，实现渐变。所以代码：

float spec = dot(worldNormal,worldHalfDir);		//高光反射系数
spec = lerp(0,1,smoothstep(-w,w,spec-threshold));
//可以理解成，图像高光区域高光反射系数就是1，非高光区域为0，
//那么我们得到的高光系数在[-w,w]的就会进行[0，1]之间的插值，实现平滑过渡。
//w我们通过邻域像素之间的近似导数值，可以通过fwidth函数得到。

四、具体实现代码：

具体解释见注释：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity Shaders Book/Chapter 14/Toon Shading" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_Ramp ("Ramp Texture", 2D) = "white" {}			//控制漫反射色调的渐变纹理
		_Outline ("Outline", Range(0, 1)) = 0.1			//控制轮廓线宽度
		_OutlineColor ("Outline Color", Color) = (0, 0, 0, 1)			//轮廓线颜色
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_SpecularScale ("Specular Scale", Range(0, 0.1)) = 0.01			//计算高光反射使用的阙值
	}
    SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}			//不透明几何体
		
		Pass {
			NAME "OUTLINE"		//第一个Pass命名
			
			Cull Front			//剔除正面
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			
			float _Outline;
			fixed4 _OutlineColor;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			}; 
			
			struct v2f {
			    float4 pos : SV_POSITION;
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				float4 pos = mul(UNITY_MATRIX_MV, v.vertex);			//顶点转到视角空间
				float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);	//法线同样，为了让描边在观察空间有更好的效果
				normal.z = -0.5;		
				pos = pos + float4(normalize(normal), 0) * _Outline;		//将顶点沿法线方向扩张
				o.pos = mul(UNITY_MATRIX_P, pos);			//最后在变换到裁剪空间
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				return float4(_OutlineColor.rgb, 1);               //使用轮廓线渲染整个背面
			}
			
			ENDCG
		}
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			Cull Back		//渲染正面
		
			CGPROGRAM
		
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_fwdbase			//前向渲染中，为Shader提供给变种，使光照变量可以被正确赋值
		
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			#include "UnityShaderVariables.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _Ramp;
			fixed4 _Specular;
			fixed _SpecularScale;
		
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
				float4 tangent : TANGENT;
			}; 
		
			struct v2f {
				float4 pos : POSITION;
				float2 uv : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
				SHADOW_COORDS(3)
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);			//偏移缩放
				o.worldNormal  = UnityObjectToWorldNormal(v.normal);			//世界空间法线和顶点位置
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				TRANSFER_SHADOW(o);		//计算阴影所需各个变量
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				fixed3 worldNormal = normalize(i.worldNormal);			//得到世界空间中归一化的各个变量
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
				
				fixed4 c = tex2D (_MainTex, i.uv);		//对纹理采样
				fixed3 albedo = c.rgb * _Color.rgb;		//材质反射率
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;		//环境光照
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);		//计算阴影值
				
				fixed diff =  dot(worldNormal, worldLightDir);		//半兰伯特光照模型
				diff = (diff * 0.5 + 0.5) * atten;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;			
				//使用上面的漫发射系数对渐变纹理采样，计算最终漫发射，
				
				fixed spec = dot(worldNormal, worldHalfDir);		//计算高光发射
				fixed w = fwidth(spec) * 2.0;			//计算w
				fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);
				//把 -( _SpecularScale - 1）当成阙值，进行[0，1]之间的平滑插值，当_SpecularScale<0.0001时，高光取消
				
				return fixed4(ambient + diffuse + specular, 1.0);//返回最终颜色
			}
		
			ENDCG
		}
	}
	FallBack "Diffuse"
}