sicp 2.42

最新推荐文章于 2024-10-12 08:15:16 发布

最新推荐文章于 2024-10-12 08:15:16 发布 · 224 阅读

SICP 专栏收录该内容

62 篇文章

订阅专栏

本文介绍了一种递归算法解决经典的八皇后问题，通过放置八个皇后在棋盘上，使得任意两个皇后都不在同一行、列及对角线上。文中详细阐述了算法实现，并提供了具体的Scheme代码实现。

Exercise 2.42.

Figure 2.8: A solution to the eight-queens puzzle.

The ``eight-queens puzzle'' asks how to place eight queens on a chessboard so that no queen is in check from any other (i.e., no two queens are in the same row, column, or diagonal). One possible solution is shown in figure 2.8. One way to solve the puzzle is to work across the board, placing a queen in each column. Once we have placed k - 1 queens, we must place the kth queen in a position where it does not check any of the queens already on the board. We can formulate this approach recursively: Assume that we have already generated the sequence of all possible ways to place k - 1 queens in the first k - 1 columns of the board. For each of these ways, generate an extended set of positions by placing a queen in each row of the kth column. Now filter these, keeping only the positions for which the queen in the kth column is safe with respect to the other queens. This produces the sequence of all ways to place k queens in the first k columns. By continuing this process, we will produce not only one solution, but all solutions to the puzzle.

We implement this solution as a procedure queens, which returns a sequence of all solutions to the problem of placing n queens on ann× n chessboard. Queens has an internal procedure queen-cols that returns the sequence of all ways to place queens in the first kcolumns of the board.

(define (queens board-size) (define (queen-cols k) (if (= k 0) (list empty-board) (filter (lambda (positions) (safe? k positions)) (flatmap (lambda (rest-of-queens) (map (lambda (new-row) (adjoin-position new-row k rest-of-queens)) (enumerate-interval 1 board-size))) (queen-cols (- k 1)))))) (queen-cols board-size))

In this procedure rest-of-queens is a way to place k - 1 queens in the first k - 1 columns, and new-row is a proposed row in which to place the queen for the kth column. Complete the program by implementing the representation for sets of board positions, including the procedure adjoin-position, which adjoins a new row-column position to a set of positions, and empty-board, which represents an empty set of positions. You must also write the procedure safe?, which determines for a set of positions, whether the queen in thekth column is safe with respect to the others. (Note that we need only check whether the new queen is safe -- the other queens are already guaranteed safe with respect to each other.)

八皇后问题，结果只保存了行，列即是list的下标

(define (queens board-size)
  (define (queen-cols k)  
    (if (= k 0)
        (list empty-board)
        (filter
         (lambda (positions) (safe? k positions))
         (flatmap
          (lambda (rest-of-queens)
            (map (lambda (new-row)
                   (adjoin-position new-row k rest-of-queens))
                 (enumerate-interval 1 board-size)))
          (queen-cols (- k 1))))))
  (queen-cols board-size))

(define empty-board '())

(define (adjoin-position new-row k rest-of-queens)
  (append rest-of-queens (list new-row)))

(define (safe? k positions)
  (if (< (length positions) 2)
      #t
      (let ((new (list-ref positions (- k 1)))
            (first (car positions)))
        (cond ((= new first) #f)
              ((= new (+ first (- (length positions) 1))) #f)
              ((= new (- first (- (length positions) 1))) #f)
              (else (safe? (- k 1) (cdr positions)))))))

(define (filter predicate sequence)  
  (cond ((null? sequence) '())  
        ((predicate (car sequence))  
         (cons (car sequence)  
               (filter predicate (cdr sequence))))  
        (else (filter predicate (cdr sequence)))))

(define (flatmap proc seq)
  (accumulate append '() (map proc seq)))

(define (accumulate op initial sequence)  
  (if (null? sequence)  
      initial  
      (op (car sequence)  
          (accumulate op initial (cdr sequence)))))

(define (enumerate-interval n m)
  (if (> n m)
      '()
      (cons n (enumerate-interval (+ n 1) m))))

(queens 8)

((1 5 8 6 3 7 2 4)

(1 6 8 3 7 4 2 5)

(1 7 4 6 8 2 5 3)

(1 7 5 8 2 4 6 3)

(2 4 6 8 3 1 7 5)

(2 5 7 1 3 8 6 4)

(2 5 7 4 1 8 6 3)

(2 6 1 7 4 8 3 5)

(2 6 8 3 1 4 7 5)

(2 7 3 6 8 5 1 4)

(2 7 5 8 1 4 6 3)

(2 8 6 1 3 5 7 4)