反射
漫反射：而当物体表面粗糙时，我们把物体表面看作无数不同方向的微小镜面，则这些镜面反射出的光方向均不相同，这就是漫反射。
高光反射：我们假定物体表面光滑，只有一个镜面，那么所有的光都被反射向了同一个方向(其实只是用时最短的光相位相似)，这就是高光反射。
逐顶点光照和逐片元光照
逐顶点光照
1.在顶点上进行光照计算，顶点间的内部区域使用插值来获取颜色信息。
2.计算量小，适用于移动设备及性能要求较高的场景。
3.效果不够精细，细节损失。明暗变化损失严重。
逐片元光照
1.每个像素单独进行光照计算。
2.精细度高，效果真实。
3.计算量大，耗费资源，适用于PC或主机游戏。
颜色相乘与颜色相加
颜色相加(复合光)：计算光照反射时使用，向白色靠拢。
颜色相乘：计算颜色混合时使用，趋于黑色。
各光照模型依次对应的效果
与本文顺序一致
兰伯特光照模型
1.理论：漫反射的强度仅与入射光的方向和反射点处表面法线的夹角余弦成正比
2.公式：漫反射光照颜色 = 光源颜色*材质的漫反射颜色*max（0，世界空间下的标准化物体表面法线向量·世界空间下的标准化后光源方向向量）
实现思路
逐顶点光照
1.材质漫反射颜色属性声明
2.渲染标签Tags设置，将LightMode光照模式设置为向前渲染
3.引用内置文件UnityCG.cginc和Lighting.cginc
4.结构体声明（裁剪空间下的顶点坐标、对应顶点的漫反射光照颜色）
5.基于公式实现逻辑（为了阴暗面不为全黑，需要加上兰伯特环境光颜色)
Shader "Unlit/Lambert" {
Properties {
// 材质漫反射颜色属性声明
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
}
SubShader {
Pass {
// 设置渲染标签 将LightMode光照模式设置为ForwardBase 向前渲染
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
//材质的漫反射颜色
fixed4 _MainColor;
//顶点着色器传递给片元着色器的内容
struct v2f {
//裁剪空间下的顶点坐标
float4 pos : SV_POSITION;
//对应顶点的漫反射光照颜色
fixed3 color : COLOR;
};
//逐顶点光照 反射光照颜色计算写在顶点着色器的回调函数中
v2f vert(appdata_base v) {
v2f v2fData;
// 模型空间 ——> 裁剪空间
v2fData.pos = UnityObjectToClipPos(v.vertex);
//模型空间下的法线 ——> 世界空间的法线
float3 normal = UnityObjectToWorldNormal(v.normal);
//世界空间下的 光源单位向量
fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(normal, lightDir));
//记录颜色 加上兰伯特光照模型的环境光变量
v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
//传出兰伯特光照
return fixed4(i.color.rgb, 1);
}
ENDCG
}
}
}
逐顶点和逐片元光照区别
1.在顶点着色器种计算顶点和法线
2.在片元着色器中计算兰伯特光照
Shader "Unlit/LambertF" {
Properties {
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "UnityCG.cginc"
//材质漫反射颜色
fixed4 _MainColor;
//顶点着色器返回出去的内容
struct v2f {
//裁剪空间的 顶点坐标
float4 pos : SV_POSITION;
//世界空间的 法线位置
float3 normal : NORMAL;
};
v2f vert(appdata_base v) {
v2f v2fData;
//模型空间——>裁剪空间 顶点
v2fData.pos = UnityObjectToClipPos(v.vertex);
//模型空间——>世界空间 法线
v2fData.normal = UnityObjectToWorldNormal(v.normal);
return v2fData;
}
//片元着色器
fixed4 frag(v2f i) : SV_TARGET {
//得到光源单位向量
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//光源颜色*材质的漫反射颜色*max（0，标准化物体表面法线向量·标准化后光源方向向量）
fixed3 color = _LightColor0.rgb * _MainColor * max(0, dot(i.normal, lightDir));
color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
return fixed4(color.rgb, 1);
}
ENDCG
}
}
}
半兰伯特光照模型
1.使物体背面拥有明暗变化
2.漫反射光照颜色 = 光源颜色*材质的漫反射颜色*(标准化后物体表面法线向量·标准化后光源方向向量*0.5f + 0.5f)
逐顶点光照
Shader "Unlit/HalfLambert" {
Properties {
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
}
SubShader {
Tags { "LightMode" = "ForwardBase" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
struct v2f {
//裁剪空间 顶点坐标
float4 pos : SV_POSITION;
//对应顶点的漫反射光照颜色
float3 color : COLOR;
};
v2f vert(appdata_base v) {
v2f v2fData;
//模型空间——>裁剪空间
v2fData.pos = UnityObjectToClipPos(v.vertex);
fixed3 normal = UnityObjectToWorldNormal(v.normal);
fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//光源颜色*材质的漫反射颜色*((0,标准物体表面法线向量·标准化后光源方向向量)*0.5+0.5)
fixed3 color = _LightColor0.rgb * _MainColor.rgb * (dot(normal,lightDir) * 0.5 + 0.5);
v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color.rgb, 1);
}
ENDCG
}
}
}
逐片元光照
Shader "Unlit/HalfLambertF" {
Properties {
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
}
SubShader {
Tags { "LightMode" = "ForwardBase" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
struct v2f {
float4 pos : SV_POSITION;
float3 normal : NORMAL;
};
v2f vert(appdata_base v) {
v2f v2fData;
v2fData.pos = UnityObjectToClipPos(v.vertex);
v2fData.normal = UnityObjectToWorldNormal(v.normal);
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 color = _LightColor0.rgb * _MainColor.rgb * (dot(i.normal, lightDir) * 0.5 + 0.5);
color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
return fixed4(color.rgb, 1);
}
ENDCG
}
}
}
Phong式高光反射光照模型
1.理论：基于光的反射行为和观察者的位置决定高光反射的表现效果。
高光反射颜色与光源的反射光线及观察者位置方向向量夹角余弦成正比
光泽度：对余弦值取n次幂
2.公式：高光反射光照颜色 = 光源颜色*材质高光反射颜色*pow(max(0，标准化后视角方向向量·标准化后的反射方向),光泽度)
实现思路
1.声明属性(材质高光反射颜色、光泽度)
2.设置渲染标签Tags LightMode为向前渲染
3.引用UnityCG.cgin和Lighting.cginc
4.结构体声明
5.公式实现
观察向量 = normalize(世界空间下的(摄像机方向 - 模型顶点位置))
反射方向 = reflect(-归一化后的世界方向下的光位置，世界方向下的法线向量)
逐顶点光照
Shader "Unlit/Phong_Specular" {
Properties {
//高光反射颜色
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
//光泽度
_SpecularNum ("SpecularNum", Range(0, 20)) = 0.5
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
//裁剪空间下 顶点坐标
float4 pos : SV_POSITION;
//颜色信息
fixed3 color : COLOR;
};
v2f vert(appdata_base v) {
v2f data;
//顶点 模型空间——>裁剪空间
data.pos = UnityObjectToClipPos(v.vertex);
//顶点 模型空间——>世界空间
float3 worldPos = mul(UNITY_MATRIX_M, v.vertex);
float3 viewDir = _WorldSpaceCameraPos.xyz - worldPos;
viewDir = normalize(viewDir);
//世界空间下的入射光
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//世界空间下的法线向量
float3 normal = UnityObjectToWorldNormal(v.normal);
//入射光的反射向量
float3 reflectDir = reflect(-lightDir, normal);
//高光反射光照颜色 = 光源的颜色 * 材质高光反射颜色 * max（0, 标准化后观察方向向量· 标准化后的反射方向）幂
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
data.color = color;
return data;
}
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color.rgb, 1);
}
ENDCG
}
}
}
逐片元光照
Shader "Unlit/PhongF_Specular" {
Properties {
//高光反射颜色
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
//光泽度
_SpecularNum ("SpecularNum", Range(0, 20)) = 1
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
//裁剪空间下 顶点坐标
float4 pos : SV_POSITION;
//世界空间下的 法线位置
fixed3 wNormal : NORMAL;
//世界空间下的 顶点坐标
float wPos : TEXCOORD0;
};
v2f vert(appdata_base v) {
v2f data;
//顶点 模型空间——>裁剪空间
data.pos = UnityObjectToClipPos(v.vertex);
//法线 模型空间——>世界空间
data.wNormal = UnityObjectToWorldNormal(v.normal);
//顶点 模型空间——>世界空间
data.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return data;
}
fixed4 frag(v2f i) : SV_Target {
//1.视角单位向量
float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.pos);
//光的方向
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//光的反射单位向量
float3 reflectDir = reflect(-lightDir, i.wNormal);
//高光反射光照颜色
//=光源颜色*材质高光反射颜色*pow(max,0,dot(视角单位向量，光的反射单位向量)),光泽度)
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0,dot(viewDir,reflectDir)),_SpecularNum);
return fixed4(color.rgb, 1);
}
ENDCG
}
}
}
Phong式光照模型
1.原理：物体表面反射光线是由三部分组成的：
环境光 + 漫反射光 + 镜面反射光（高光反射）
其中：
环境光颜色 = UNITY_LIGHTMODEL_AMBIENT(unity_AmbientSky、unity_AmbientEquator、unity_AmbientGround)
漫反射颜色 = 兰伯特光照模型
高光反射颜色 = Phong式高光反射光照模型
逐顶点光照
Shader "Unlit/Phong" {
Properties {
//材质的漫反射光照颜色
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
//高光反射颜色
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
//光泽度
_SpecularNum ("SpecularNum", Range(0, 20)) = 1
}
SubShader {
//设置光照模式 ForwardBase向前渲染模式 主要是用来处理 不透明物体的 光照渲染的
Tags { "LightMode" = "ForwardBase" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
//裁剪空间下 顶点坐标
float4 pos : SV_POSITION;
//漫反射光照颜色
fixed3 color : COLOR;
};
//漫反射光（兰伯特光照模型）
fixed3 getLambertColor(in float3 objNormal) {
float3 normal = UnityObjectToWorldDir(objNormal);
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//兰伯特光照模型
//光照颜色 * 材质漫反射颜色 * max(0, dot(法线方向向量，光源方向向量))
fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(normal, lightDir));
return color;
}
//计算Phong高光反射光照模型
fixed3 getSpecularColor(in float4 objVertex, in float3 objNormal) {
//标准化后的观察方向
float3 worldPos = mul(UNITY_MATRIX_M, objVertex);
float3 viewDir = _WorldSpaceCameraPos.xyz - worldPos;
viewDir = normalize(viewDir);
//标准化后的反射方向
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
float3 normal = UnityObjectToWorldNormal(objNormal);
float3 reflectDir = reflect(-lightDir, normal);
//光反射光照颜色 = 光源的颜色 * 材质高光反射颜色 * max（0, 标准化后观察方向向量· 标准化后的反射方向）幂
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(viewDir, reflectDir)), _SpecularNum);
return color;
}
v2f vert(appdata_base v) {
v2f v2fData;
//顶点 模型空间——>裁剪空间
v2fData.pos = UnityObjectToClipPos(v.vertex);
//计算兰伯特光照模型所得颜色
fixed3 lambertColor = getLambertColor(v.normal);
//计算Phong式高光反射光照模型所得颜色
fixed3 specularColor = getSpecularColor(v.vertex, v.normal);
//Phong光照模型公式
//物体表面光照颜色 = 环境光颜色 + 兰伯特光照模型所得颜色 + Phong式高光反射光照模型所得颜色
v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + lambertColor + specularColor;
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color.rgb, 1);
}
ENDCG
}
}
}
逐片元光照
Shader "Unlit/PhongF" {
Properties {
//材质的漫反射光照颜色
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
//高光反射颜色
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
//光泽度
_SpecularNum ("SpecularNum", Range(0, 20)) = 1
}
SubShader {
//设置光照模式 ForwardBase向前渲染模式 主要是用来处理 不透明物体的 光照渲染的
Tags { "LightMode" = "ForwardBase" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
//裁剪空间下的顶点位置
float4 pos:SV_POSITION;
//世界空间下的法线位置
float3 wNormal:NORMAL;
//世界空间下的 顶点坐标
float3 wPos:TEXCOORD0;
};
//得到兰伯特光照模型计算的颜色 （逐片元）
fixed3 getLambertFColor(in float3 wNormal)
{
//得到光源单位向量
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//计算除了兰伯特光照的漫反射颜色
fixed3 color = _LightColor0.rgb * _MainColor.rgb * max(0, dot(wNormal, lightDir));
return color;
}
//得到Phong式高光反射模型计算的颜色（逐片元）
fixed3 getSpecularColor(in float3 wPos, in float3 wNormal)
{
//1.视角单位向量
float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - wPos );
//2.光的反射单位向量
//光的方向
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//光反射光线的单位向量
float3 reflectDir = reflect(-lightDir, wNormal);
//color = 光源颜色 * 材质高光反射颜色 * pow( max(0, dot(视角单位向量, 光的反射单位向量)), 光泽度 )
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow( max(0, dot(viewDir, reflectDir)), _SpecularNum );
return color;
}
v2f vert (appdata_base v)
{
v2f v2fData;
//转换模型空间下的顶点到裁剪空间中
v2fData.pos = UnityObjectToClipPos(v.vertex);
//转换模型空间下的法线到世界空间下
v2fData.wNormal = UnityObjectToWorldNormal(v.normal);
//顶点转到世界空间
v2fData.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return v2fData;
}
fixed4 frag (v2f i) : SV_Target
{
//计算兰伯特光照颜色
fixed3 lambertColor = getLambertFColor(i.wNormal);
//计算Phong式高光反射颜色
fixed3 specularColor = getSpecularColor(i.wPos, i.wNormal);
//物体表面光照颜色 = 环境光颜色 + 兰伯特光照模型所得颜色 + Phong式高光反射光照模型所得颜色
fixed3 phongColor = UNITY_LIGHTMODEL_AMBIENT.rgb + lambertColor + specularColor;
return fixed4(phongColor.rgb, 1);
}
ENDCG
}
}
}
Blinn-Phong式高光反射光照模型
1.对Phong式高光反射模型的改进：不使用反射向量计算镜面反射，而使用半角向量计算
2.公式：高光反射光照颜色 = 光源颜色*材质高光反射颜色*pow(max(0,标准化后顶点法线方向向量·标准化后半角向量方向向量),光泽度)
其中：
半角向量：视角方向和光线方向的角平分线 = 视角单位向量 + 入射光单位向量
光泽度：对余弦值取n次幂
逐顶点光照
Shader "Unlit/BlinnPhongSpecular" {
Properties {
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
_SpecularNum ("SpecularNum", Range(0, 20)) = 5
}
SubShader {
Pass
{
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct v2f
{
//裁剪空间的位置
float4 pos:SV_POSITION;
//基于世界坐标系下的顶点位置
float3 wPos:TEXCOORD0;
//基于世界坐标系下的发现
float3 wNormal:NORMAL;
};
fixed4 _SpecularColor;
float _SpecularNum;
v2f vert (appdata_base v)
{
v2f data;
//顶点转到裁剪空间
data.pos = UnityObjectToClipPos(v.vertex);
//把顶点从模型空间转换到世界空间中 进行矩阵乘法运算
data.wPos = mul(unity_ObjectToWorld, v.vertex);
//法线计算
data.wNormal = UnityObjectToWorldNormal(v.normal);
return data;
}
fixed4 frag (v2f i) : SV_Target
{
//高光反射光照颜色 = 光源的颜色 * 材质高光反射颜色 * max（0, 标准化后顶点法线方向向量 · 标准化后半角向量方向向量）幂
float3 viewDir = normalize( _WorldSpaceCameraPos.xyz - i.wPos );
//光线方向 单位向量
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//半角方向向量
float3 halfA = normalize(viewDir + lightDir);
//高光反射光照颜色 = 光源的颜色 * 材质高光反射颜色 * max（0, 标准化后顶点法线方向向量 · 标准化后半角向量方向向量）幂
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow( max(0, dot(i.wNormal, halfA)) , _SpecularNum);
return fixed4(color.rgb, 1);
}
ENDCG
}
}
}
逐片元光照
Shader "Unlit/BlinnPhongSpecularF" {
Properties {
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
_SpecularNum ("SpecularNum", Range(0, 20)) = 5
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include"Lighting.cginc"
struct v2f {
float4 pos : SV_POSITION;
float3 wPos : TEXCOORD0;
float3 wNormal : NORMAL;
};
fixed4 _SpecularColor;
float _SpecularNum;
v2f vert(appdata_base v) {
v2f data;
data.pos = UnityObjectToClipPos(v.vertex);
data.wPos = mul(unity_ObjectToWorld, v.vertex);
data.wNormal = UnityObjectToWorldNormal(v.normal);
return data;
}
fixed4 frag(v2f i) : SV_Target {
float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.wPos);
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
float3 halfA = normalize(viewDir + lightDir);
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(i.wNormal, halfA)), _SpecularNum);
return fixed4(color.rgb, 1);
}
ENDCG
}
}
}
Blinn-Phong式光照模型
1.原理：物体表面反射光线由三部分组成
环境光+漫反射光+镜面反射光（高光反射光）
其中：
高光反射颜色 = BlinnPhong式高光反射光照模型
逐顶点光照
Shader "Unlit/BlinnPhong" {
Properties {
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
_SpecularNum ("SpecularNum", Range(0, 20)) = 0.5
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
float4 pos : SV_POSITION;
fixed3 color : COLOR;
};
fixed3 getLambertColor(in float3 objNormal) {
float3 normal = UnityObjectToWorldNormal(objNormal);
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 color = _LightColor0.rgb * _MainColor * max(0, dot(normal, lightDir));
return color;
}
fixed3 getSpecularColor(in float4 objVertex, in float3 objNormal) {
float3 worldPos = mul(UNITY_MATRIX_M, objVertex);
float3 viewDir = _WorldSpaceCameraPos.xyz - worldPos;
viewDir = normalize(viewDir);
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
float3 normal = UnityObjectToWorldNormal(objNormal);
float3 halfA = normalize(viewDir + lightDir);
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(normal, halfA)), _SpecularNum);
return color;
}
v2f vert(appdata_base v) {
v2f v2fData;
v2fData.pos = UnityObjectToClipPos(v.vertex);
fixed3 lambertColor = getLambertColor(v.normal);
fixed3 specularColor = getSpecularColor(v.vertex, v.normal);
v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + lambertColor + specularColor;
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color.rgb, 1);
}
ENDCG
}
}
}
逐片元光照
Shader "Unlit/BlinnPhongF" {
Properties {
_MainColor ("MainColor", Color) = (1, 1, 1, 1)
//高光反射颜色 光泽度
_SpecularColor ("SpecularColor", Color) = (1, 1, 1, 1)
_SpecularNum ("SpecularNum", Range(0, 20)) = 1
}
SubShader {
Pass {
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _MainColor;
fixed4 _SpecularColor;
float _SpecularNum;
struct v2f {
float4 pos : SV_POSITION;
fixed3 wNormal : NORMAL;
float3 wPos : TEXCOORD0;
};
fixed3 getLambertColor(in float3 wNormal) {
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 color = _LightColor0.rgb * _MainColor * max(0, dot(wNormal, lightDir));
return color;
}
fixed3 getSpecularColor(in float3 wPos, in float3 wNormal) {
float3 viewDir = _WorldSpaceCameraPos.xyz - wPos;
viewDir = normalize(viewDir);
float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
float3 halfA = normalize(viewDir + lightDir);
fixed3 color = _LightColor0.rgb * _SpecularColor.rgb * pow(max(0, dot(wNormal, halfA)), _SpecularNum);
return color;
}
v2f vert(appdata_base v) {
v2f v2fData;
v2fData.pos = UnityObjectToClipPos(v.vertex);
v2fData.wNormal = UnityObjectToWorldNormal(v.normal);
v2fData.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return v2fData;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 lambertColor = getLambertColor(i.wNormal);
fixed3 specularColor = getSpecularColor(i.wPos, i.wNormal);
//物体表面光照颜色 = 环境光颜色 + 兰伯特光照模型所得颜色 + Phong式高光反射光照模型所得颜色
fixed3 blinnPhongColor = UNITY_LIGHTMODEL_AMBIENT.rgb + lambertColor + specularColor;
return fixed4(blinnPhongColor.rgb, 1);
}
ENDCG
}
}
}
两种高光反射的区别
| Blinn-Phong | Phong | |
| 高光散射 | 均匀而光滑 | 锐利，会有区域较亮与较暗 |
| 高光锐度 | 较广，不锐利 | 锐利 |
| 光滑度与表面纹理 | 更光滑，光照均匀分布 |
1.表现具有粗糙表面纹理 2.物体高光散射使纹理和细节更突出 |
| 镜面高光 | 大，均匀分布 | 小，锐利 |
| 性能 | 较好 | 较差 |
扫一扫
2496
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
