# Chapter 33. Writing Custom Plugins

A Gradle plugin packages up some reusable piece of build logic, which can be used across many different projects and builds. Gradle allows you to implement your own custom plugins, so you can reuse your build logic, and potentially share it with others.

You can implement a custom plugin in any language you like, provided the implementation ends up compiled as class files. For the examples here, we are going to use Groovy as the implementation language. You could use Java or Scala instead, if you wanted.

There are several places where you can put the source for the plugin. Two convenient options are to add the task implementation to your build script, or to put the source in the ``rootProjectDir`/buildSrc/src/main/groovy` directory. Gradle will take care of compiling the task and making it available on the classpath of the build script. See Chapter 34, Organizing Build Logic for more details, and some other options. In our examples, we will put the task implementation in the build script, to keep things simple.

To create a custom plugin, you need to write an implementation of `Plugin` . Gradle instantiates the plugin and calls the plugin instance's `use()` method when the plugin is used with a project. The project object is passed as a parameter, which the plugin can use to configure the project however it needs to. The following sample contains a greeting plugin, which adds a `hello` task to the project.

Example 33.1. A custom plugin

`build.gradle`

    usePlugin(GreetingPlugin)

    class GreetingPlugin implements Plugin {
        def void use(Project project, ProjectPluginsContainer projectPluginsHandler) {
            project.task('hello') << {
                println "Hello from the GreetingPlugin"
            }
        }
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hello from the GreetingPlugin

One thing to note is that only one instance of a given plugin is created for a given build. The same plugin instance is used for all projects in the build.

Let's add a convention object to the project. Here we add a `greeting` property to the project, which allows you to configure the greeting.

Example 33.2. A custom plugin convention

`build.gradle`

    usePlugin(GreetingPlugin)

    greeting = 'Hi from Gradle'

    class GreetingPlugin implements Plugin {
        def void use(Project project, ProjectPluginsContainer projectPluginsHandler) {
            project.convention.plugins.greeting = new GreetingPluginConvention()
            project.task('hello') << {
                println project.greeting
            }
        }
    }

    class GreetingPluginConvention {
        def String greeting = 'Hello from GreetingPlugin'
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle