本文介绍了PS2游戏手柄的通信协议，包括接收器引脚功能、通信时序以及代码解读。在Arduino环境下，通过PS2X库实现了与手柄的交互，包括配置手柄、读取按键状态等功能。代码示例展示了如何使用库文件进行手柄的初始化和数据读取，从而帮助开发者更好地进行游戏手柄的二次开发。
ps2手柄是索尼的PlayStation2游戏机的遥控手柄。
该款手柄的通讯协议被游戏爱好者破解，使得手柄可以接在其他器件上遥控使用，比如遥控我们熟悉的智能小车。
突出的特点是这款手柄性价比极高，按键丰富，方便扩展到其它应用中。
1.PS手柄介绍
ps2手柄由手柄与接收器两部分组成。
接收器与单片机相连，用于接收手柄发来的信息，将信号传递给单片机。
单片机也可通过接收器，向手柄发送命令，配置手柄的发送模式。
接收器引脚输出：
DI/DAT：信号流向，从手柄到主机，此信号是一个8bit的串行数据，同步传送于时钟的下降沿。信号的读取在时钟由高到低的变化过程中完成。
DO/CMD：信号流向，从主机到手柄，此信号和DI相对，信号是一个8bit的串行数据，同步传送于时钟的下降沿。
NC：空端口；
GND：电源地；
VDD：接收器工作电源，电源范围3~5V；
CS/SEL：用于提供手柄触发信号。在通讯期间，处于低电平；
CLK：时钟信号，由主机发出，用于保持数据同步；
NC：空端口；
ACK：从手柄到主机的应答信号。此信号在每个8bits数据发送的最后一个周期变低并且CS一直保持低电平，如果CS信号不变低，约60微秒PS主机会试另一个外设。在编程时未使用ACK端口。
通信时序：
-
CS线在通讯期间拉低，通信过程中CS信号线在一串数据（9个字节,每个字节为8位）发送完毕后才会拉高，而不是每个字节发送完拉高。
-
DO、DI在在CLK时钟的下降沿完成数据的发送和读取。
时钟频率250KHz（4us），如果接收数据不稳定，可以适当的增加频率。
在通讯过程中，一串数据通讯完成后CS才会由低转高，不是1个字节通讯完成后就由低转高，在通讯期间，一直处于低电平。
在时钟下降沿时，完成数据（1bit）的发送与接收，发送和接收是同时完成的。
当单片机想读手柄数据或向手柄发送命令时，将会拉低CS线电平，并发出一个命令“0x01”；手柄会回复它的ID“0x41=绿灯模式（非模拟模式），0x73=红灯模式（模拟模式）”；
在手柄发送ID的同时，单片机将传送0x42，请求数据；随后手柄发送出0x5A，告诉单片机“数据来了”。
idle：数据线空闲，该数据线无数据传送。一个通讯周期有9个字节（8位），这些数据是依次按位传送。
主要的通信协议如下：
2、代码解读
这里我们来学习下ardunio的库文件
首先在https://github.com/madsci1016/Arduino-PS2X 这里下载ps2x的库文件。
将PS2X_lib放到库文件目录下。
接线方法如下：
PS2X_Example.ino 文件解读：
#include <PS2X_lib.h> //for v1.6 关联库文件
/******************************************************************
//接线管脚定义
******************************************************************/
#define PS2_DAT 13
#define PS2_CMD 11
#define PS2_SEL 10
#define PS2_CLK 12
/******************************************************************
* select modes of PS2 controller:
* 选择PS2的控制模式
* - pressures = 按键模拟量方式读取
* - rumble = motor rumbling (尚未了解)
******************************************************************/
//#define pressures true
#define pressures false
//#define rumble true
#define rumble false
PS2X ps2x; // create PS2 Controller Class 创建对象
//right now, the library does NOT support hot pluggable controllers, meaning
//you must always either restart your Arduino after you connect the controller,
//or call config_gamepad(pins) again after connecting the controller.
int error = 0;
byte type = 0;
byte vibrate = 0;
// Reset func
void (* resetFunc) (void) = 0;
//初始化
void setup(){
Serial.begin(115200); //设置串口波特率
delay(500); //added delay to give wireless ps2 module some time to startup, before configuring it
//CHANGES for v1.6 HERE!!! **************PAY ATTENTION*************
//setup pins and settings: GamePad(clock, command, attention, data, Pressures?, Rumble?) check for error
error = ps2x.config_gamepad(PS2_CLK, PS2_CMD, PS2_SEL, PS2_DAT, pressures, rumble);
if(error == 0){
Serial.print("Found Controller, configured successful ");
Serial.print("pressures = ");
if (pressures)
Serial.println("true ");
else
Serial.println("false");
Serial.print("rumble = ");
if (rumble)
Serial.println("true)");
else
Serial.println("false");
Serial.println("Try out all the buttons, X will vibrate the controller, faster as you press harder;");
Serial.println("holding L1 or R1 will print out the analog stick values.");
Serial.println("Note: Go to www.billporter.info for updates and to report bugs.");
}
else if(error == 1)
Serial.println("No controller found, check wiring, see readme.txt to enable debug. visit www.billporter.info for troubleshooting tips");
else if(error == 2)
Serial.println("Controller found but not accepting commands. see readme.txt to enable debug. Visit www.billporter.info for troubleshooting tips");
else if(error == 3)
Serial.println("Controller refusing to enter Pressures mode, may not support it. ");
type = ps2x.readType();
switch(type) {
case 0:
Serial.println("Unknown Controller type found ");
break;
case 1:
Serial.println("DualShock Controller found ");
break;
case 2:
Serial.println("GuitarHero Controller found ");
break;
case 3:
Serial.println("Wireless Sony DualShock Controller found ");
break;
}
}
void loop() {
/* You must Read Gamepad to get new values and set vibration values
ps2x.read_gamepad(small motor on/off, larger motor strenght from 0-255)
if you don't enable the rumble, use ps2x.read_gamepad(); with no values
You should call this at least once a second
*/
if(error == 1){ //skip loop if no controller found
resetFunc();
}
if(type == 2){ //Guitar Hero Controller
ps2x.read_gamepad(); //read controller
if(ps2x.ButtonPressed(GREEN_FRET))
Serial.println("Green Fret Pressed");
if(ps2x.ButtonPressed(RED_FRET))
Serial.println("Red Fret Pressed");
if(ps2x.ButtonPressed(YELLOW_FRET))
Serial.println("Yellow Fret Pressed");
if(ps2x.ButtonPressed(BLUE_FRET))
Serial.println("Blue Fret Pressed");
if(ps2x.ButtonPressed(ORANGE_FRET))
Serial.println("Orange Fret Pressed");
if(ps2x.ButtonPressed(STAR_POWER))
Serial.println("Star Power Command");
if(ps2x.Button(UP_STRUM)) //will be TRUE as long as button is pressed
Serial.println("Up Strum");
if(ps2x.Button(DOWN_STRUM))
Serial.println("DOWN Strum");
if(ps2x.Button(PSB_START)) //will be TRUE as long as button is pressed
Serial.println("Start is being held");
if(ps2x.Button(PSB_SELECT))
Serial.println("Select is being held");
if(ps2x.Button(ORANGE_FRET)) { // print stick value IF TRUE
Serial.print("Wammy Bar Position:");
Serial.println(ps2x.Analog(WHAMMY_BAR), DEC);
}
}
else { //DualShock Controller
ps2x.read_gamepad(false, vibrate); //read controller and set large motor to spin at 'vibrate' speed
if(ps2x.Button(PSB_START)) //will be TRUE as long as button is pressed
Serial.println("Start is being held");
if(ps2x.Button(PSB_SELECT))
Serial.println("Select is being held");
if(ps2x.Button(PSB_PAD_UP)) { //will be TRUE as long as button is pressed
Serial.print("Up held this hard: ");
Serial.println(ps2x.Analog(PSAB_PAD_UP), DEC);
}
if(ps2x.Button(PSB_PAD_RIGHT)){
Serial.print("Right held this hard: ");
Serial.println(ps2x.Analog(PSAB_PAD_RIGHT), DEC);
}
if(ps2x.Button(PSB_PAD_LEFT)){
Serial.print("LEFT held this hard: ");
Serial.println(ps2x.Analog(PSAB_PAD_LEFT), DEC);
}
if(ps2x.Button(PSB_PAD_DOWN)){
Serial.print("DOWN held this hard: ");
Serial.println(ps2x.Analog(PSAB_PAD_DOWN), DEC);
}
vibrate = ps2x.Analog(PSAB_CROSS); //this will set the large motor vibrate speed based on how hard you press the blue (X) button
if (ps2x.NewButtonState()) { //will be TRUE if any button changes state (on to off, or off to on)
if(ps2x.Button(PSB_L3))
Serial.println("L3 pressed");
if(ps2x.Button(PSB_R3))
Serial.println("R3 pressed");
if(ps2x.Button(PSB_L2))
Serial.println("L2 pressed");
if(ps2x.Button(PSB_R2))
Serial.println("R2 pressed");
if(ps2x.Button(PSB_TRIANGLE))
Serial.println("Triangle pressed");
}
if(ps2x.ButtonPressed(PSB_CIRCLE)) //will be TRUE if button was JUST pressed
Serial.println("Circle just pressed");
if(ps2x.NewButtonState(PSB_CROSS)) //will be TRUE if button was JUST pressed OR released
Serial.println("X just changed");
if(ps2x.ButtonReleased(PSB_SQUARE)) //will be TRUE if button was JUST released
Serial.println("Square just released");
if(ps2x.Button(PSB_L1) || ps2x.Button(PSB_R1)) { //print stick values if either is TRUE
Serial.print("Stick Values:");
Serial.print(ps2x.Analog(PSS_LY), DEC); //Left stick, Y axis. Other options: LX, RY, RX
Serial.print(",");
Serial.print(ps2x.Analog(PSS_LX), DEC);
Serial.print(",");
Serial.print(ps2x.Analog(PSS_RY), DEC);
Serial.print(",");
Serial.println(ps2x.Analog(PSS_RX), DEC);
}
}
delay(50);
}
从上面的示例代码中，我们了解到ardunio的开发文档里首先关联了库函数
#include <PS2X_lib.h> //for v1.6 关联库文件
然后对接收器的管脚定义：
#define PS2_DAT 13
#define PS2_CMD 11
#define PS2_SEL 10
#define PS2_CLK 12
创建手柄对象：
PS2X ps2x; // create PS2 Controller Class 创建对象
运用串口工具进行调试，在setup() 初始化函数里首先配置了串口，
接着调用手柄配置函数进行配置
error = ps2x.config_gamepad(PS2_CLK, PS2_CMD, PS2_SEL, PS2_DAT, pressures, rumble);
通过返回值确认手柄配置是否成功，进而识别手柄的类型。
type = ps2x.readType();
在循环体loop()函数中：
针对不同的手柄类型，进行按键的读取。
总结：通过这段代码很容易开展游戏手柄的开发。
接着我们进一步分析库文件对手柄的数据结构的定义以及驱动部分，进而学习手柄的通信协议。
不过今天的重点我们放在如何开展通信层的驱动上。
3、库文件解读
/******************************************************************
* Super amazing PS2 controller Arduino Library v1.8
* details and example sketch:
* http://www.billporter.info/?p=240
*
* Original code by Shutter on Arduino Forums
*
* Revamped, made into lib by and supporting continued development:
* Bill Porter
* www.billporter.info
*
* Contributers:
* Eric Wetzel (thewetzel@gmail.com)
* Kurt Eckhardt
*
* Lib version history
* 0.1 made into library, added analog stick support.
* 0.2 fixed config_gamepad miss-spelling
* added new functions:
* NewButtonState();
* NewButtonState(unsigned int);
* ButtonPressed(unsigned int);
* ButtonReleased(unsigned int);
* removed 'PS' from begining of ever function
* 1.0 found and fixed bug that wasn't configuring controller
* added ability to define pins
* added time checking to reconfigure controller if not polled enough
* Analog sticks and pressures all through 'ps2x.Analog()' function
* added:
* enableRumble();
* enablePressures();
* 1.1
* added some debug stuff for end user. Reports if no controller found
* added auto-increasing sentence delay to see if it helps compatibility.
* 1.2
* found bad math by Shutter for original clock. Was running at 50kHz, not the required 500kHz.
* fixed some of the debug reporting.
* 1.3
* Changed clock back to 50kHz. CuriousInventor says it's suppose to be 500kHz, but doesn't seem to work for everybody.
* 1.4
* Removed redundant functions.
* Fixed mode check to include two other possible modes the controller could be in.
* Added debug code enabled by compiler directives. See below to enable debug mode.
* Added button definitions for shapes as well as colors.
* 1.41
* Some simple bug fixes
* Added Keywords.txt file
* 1.5
* Added proper Guitar Hero compatibility
* Fixed issue with DEBUG mode, had to send serial at once instead of in bits
* 1.6
* Changed config_gamepad() call to include rumble and pressures options
* This was to fix controllers that will only go into config mode once
* Old methods should still work for backwards compatibility
* 1.7
* Integrated Kurt's fixes for the interrupts messing with servo signals
* Reorganized directory so examples show up in Arduino IDE menu
* 1.8
* Added Arduino 1.0 compatibility.
* 1.9
* Kurt - Added detection and recovery from dropping from analog mode, plus
* integreated Chipkit (pic32mx...) support
*
*
*
*This program is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
<http://www.gnu.org/licenses/>
*
******************************************************************/
// $$$$$$$$$$$$ DEBUG ENABLE SECTION $$$$$$$$$$$$$$$$
// to debug ps2 controller, uncomment these two lines to print out debug to uart
#define PS2X_DEBUG
//#define PS2X_COM_DEBUG
#ifndef PS2X_lib_h
#define PS2X_lib_h
#if ARDUINO > 22
#include "Arduino.h"
#else
#include "WProgram.h"
#endif
#include <math.h>
#include <stdio.h>
#include <stdint.h>
#ifdef __AVR__
// AVR
#include <avr/io.h>
#define CTRL_CLK 4
#define CTRL_BYTE_DELAY 3
#else
// Pic32...
#include <pins_arduino.h>
#define CTRL_CLK 5
#define CTRL_CLK_HIGH 5
#define CTRL_BYTE_DELAY 4
#endif
//These are our button constants
#define PSB_SELECT 0x0001
#define PSB_L3 0x0002
#define PSB_R3 0x0004
#define PSB_START 0x0008
#define PSB_PAD_UP 0x0010
#define PSB_PAD_RIGHT 0x0020
#define PSB_PAD_DOWN 0x0040
#define PSB_PAD_LEFT 0x0080
#define PSB_L2 0x0100
#define PSB_R2 0x0200
#define PSB_L1 0x0400
#define PSB_R1 0x0800
#define PSB_GREEN 0x1000
#define PSB_RED 0x2000
#define PSB_BLUE 0x4000
#define PSB_PINK 0x8000
#define PSB_TRIANGLE 0x1000
#define PSB_CIRCLE 0x2000
#define PSB_CROSS 0x4000
#define PSB_SQUARE 0x8000
//Guitar button constants
#define UP_STRUM 0x0010
#define DOWN_STRUM 0x0040
#define STAR_POWER 0x0100
#define GREEN_FRET 0x0200
#define YELLOW_FRET 0x1000
#define RED_FRET 0x2000
#define BLUE_FRET 0x4000
#define ORANGE_FRET 0x8000
#define WHAMMY_BAR 8
//These are stick values
#define PSS_RX 5
#define PSS_RY 6
#define PSS_LX 7
#define PSS_LY 8
//These are analog buttons
#define PSAB_PAD_RIGHT 9
#define PSAB_PAD_UP 11
#define PSAB_PAD_DOWN 12
#define PSAB_PAD_LEFT 10
#define PSAB_L2 19
#define PSAB_R2 20
#define PSAB_L1 17
#define PSAB_R1 18
#define PSAB_GREEN 13
#define PSAB_RED 14
#define PSAB_BLUE 15
#define PSAB_PINK 16
#define PSAB_TRIANGLE 13
#define PSAB_CIRCLE 14
#define PSAB_CROSS 15
#define PSAB_SQUARE 16
#define SET(x,y) (x|=(1<<y))
#define CLR(x,y) (x&=(~(1<<y)))
#define CHK(x,y) (x & (1<<y))
#define TOG(x,y) (x^=(1<<y))
class PS2X {
public:
boolean Button(uint16_t); //will be TRUE if button is being pressed
unsigned int ButtonDataByte();
boolean NewButtonState();
boolean NewButtonState(unsigned int); //will be TRUE if button was JUST pressed OR released
boolean ButtonPressed(unsigned int); //will be TRUE if button was JUST pressed
boolean ButtonReleased(unsigned int); //will be TRUE if button was JUST released
void read_gamepad();
boolean read_gamepad(boolean, byte);
byte readType();
byte config_gamepad(uint8_t, uint8_t, uint8_t, uint8_t);
byte config_gamepad(uint8_t, uint8_t, uint8_t, uint8_t, bool, bool);
void enableRumble();
bool enablePressures();
byte Analog(byte);
void reconfig_gamepad();
private:
inline void CLK_SET(void);
inline void CLK_CLR(void);
inline void CMD_SET(void);
inline void CMD_CLR(void);
inline void ATT_SET(void);
inline void ATT_CLR(void);
inline bool DAT_CHK(void);
unsigned char _gamepad_shiftinout (char);
unsigned char PS2data[21];
void sendCommandString(byte*, byte);
unsigned char i;
unsigned int last_buttons;
unsigned int buttons;
#ifdef __AVR__
uint8_t maskToBitNum(uint8_t);
uint8_t _clk_mask;
volatile uint8_t *_clk_oreg;
uint8_t _cmd_mask;
volatile uint8_t *_cmd_oreg;
uint8_t _att_mask;
volatile uint8_t *_att_oreg;
uint8_t _dat_mask;
volatile uint8_t *_dat_ireg;
#else
uint8_t maskToBitNum(uint8_t);
uint16_t _clk_mask;
volatile uint32_t *_clk_lport_set;
volatile uint32_t *_clk_lport_clr;
uint16_t _cmd_mask;
volatile uint32_t *_cmd_lport_set;
volatile uint32_t *_cmd_lport_clr;
uint16_t _att_mask;
volatile uint32_t *_att_lport_set;
volatile uint32_t *_att_lport_clr;
uint16_t _dat_mask;
volatile uint32_t *_dat_lport;
#endif
unsigned long last_read;
byte read_delay;
byte controller_type;
boolean en_Rumble;
boolean en_Pressures;
};
#endif
库文件.h中，定义了按键 、手柄类、以及操作函数。
接着我们再来学习下.cpp文件
1、通信管脚的操作：
//管脚寄存器映射
_clk_mask = digitalPinToBitMask(clk);
_clk_oreg = portOutputRegister(digitalPinToPort(clk));
_cmd_mask = digitalPinToBitMask(cmd);
_cmd_oreg = portOutputRegister(digitalPinToPort(cmd));
_att_mask = digitalPinToBitMask(att);
_att_oreg = portOutputRegister(digitalPinToPort(att));
_dat_mask = digitalPinToBitMask(dat);
_dat_ireg = portInputRegister(digitalPinToPort(dat));
//时钟线拉高
inline void PS2X::CLK_SET(void) {
register uint8_t old_sreg = SREG;
cli();
*_clk_oreg |= _clk_mask;
SREG = old_sreg;
}
//时钟线拉低
inline void PS2X::CLK_CLR(void) {
register uint8_t old_sreg = SREG;
cli();
*_clk_oreg &= ~_clk_mask;
SREG = old_sreg;
}
//DO 控制线拉高
inline void PS2X::CMD_SET(void) {
register uint8_t old_sreg = SREG;
cli();
*_cmd_oreg |= _cmd_mask; // SET(*_cmd_oreg,_cmd_mask);
SREG = old_sreg;
}
//DO 控制线拉低
inline void PS2X::CMD_CLR(void) {
register uint8_t old_sreg = SREG;
cli();
*_cmd_oreg &= ~_cmd_mask; // SET(*_cmd_oreg,_cmd_mask);
SREG = old_sreg;
}
//DI 拉高
inline void PS2X::ATT_SET(void) {
register uint8_t old_sreg = SREG;
cli();
*_att_oreg |= _att_mask ;
SREG = old_sreg;
}
//DI 拉低
inline void PS2X::ATT_CLR(void) {
register uint8_t old_sreg = SREG;
cli();
*_att_oreg &= ~_att_mask;
SREG = old_sreg;
}
inline bool PS2X::DAT_CHK(void) {
return (*_dat_ireg & _dat_mask) ? true : false;
}
2、 通信数据传送
通讯时序上可以看出，发送和接收是同时进行的。
unsigned char PS2X::_gamepad_shiftinout (char byte) {
unsigned char tmp = 0;
for(unsigned char i=0;i<8;i++) {
if(CHK(byte,i)) CMD_SET();
else CMD_CLR();
CLK_CLR(); //时钟线下降沿
delayMicroseconds(CTRL_CLK);
//if(DAT_CHK()) SET(tmp,i);
if(DAT_CHK()) bitSet(tmp,i); //读取DI
CLK_SET(); // 始终线上升
#if CTRL_CLK_HIGH
delayMicroseconds(CTRL_CLK_HIGH);
#endif
}
CMD_SET(); //DO 控制线拉高
delayMicroseconds(CTRL_BYTE_DELAY);
return tmp;
}
3、读取按键
boolean PS2X::read_gamepad(boolean motor1, byte motor2) {
double temp = millis() - last_read;
if (temp > 1500) //waited to long
reconfig_gamepad();
if(temp < read_delay) //waited too short
delay(read_delay - temp);
if(motor2 != 0x00)
motor2 = map(motor2,0,255,0x40,0xFF); //noting below 40 will make it spin
char dword[9] = {0x01,0x42,0,motor1,motor2,0,0,0,0};
byte dword2[12] = {0,0,0,0,0,0,0,0,0,0,0,0};
// Try a few times to get valid data...
for (byte RetryCnt = 0; RetryCnt < 5; RetryCnt++) {
CMD_SET(); //先保证高电平
CLK_SET(); //先保证高电平
ATT_CLR(); // 拉低CS 类似SPI中片选，表示接下来开始传送数据。
delayMicroseconds(CTRL_BYTE_DELAY);
//Send the command to send button and joystick data;
for (int i = 0; i<9; i++) {
PS2data[i] = _gamepad_shiftinout(dword[i]);
}
if(PS2data[1] == 0x79) { //if controller is in full data return mode, get the rest of data
for (int i = 0; i<12; i++) {
PS2data[i+9] = _gamepad_shiftinout(dword2[i]);
}
}
ATT_SET(); // HI disable joystick
// Check to see if we received valid data or not.
// We should be in analog mode for our data to be valid (analog == 0x7_)
if ((PS2data[1] & 0xf0) == 0x70)
break;
// If we got to here, we are not in analog mode, try to recover...
reconfig_gamepad(); // try to get back into Analog mode.
delay(read_delay);
}
// If we get here and still not in analog mode (=0x7_), try increasing the read_delay...
if ((PS2data[1] & 0xf0) != 0x70) {
if (read_delay < 10)
read_delay++; // see if this helps out...
}
#ifdef PS2X_COM_DEBUG
//Serial.println("OUT:IN");
for(int i=0; i<9; i++){
//Serial.print(dword[i], HEX);
//Serial.print(":");
//Serial.print(PS2data[i], HEX);
//Serial.print(" ");
}
for (int i = 0; i<12; i++) {
//Serial.print(dword2[i], HEX);
//Serial.print(":");
//Serial.print(PS2data[i+9], HEX);
//Serial.print(" ");
}
//Serial.println("");
#endif
last_buttons = buttons; //store the previous buttons states
#if defined(__AVR__)
buttons = *(uint16_t*)(PS2data+3); //store as one value for multiple functions
#else
buttons = (uint16_t)(PS2data[4] << 8) + PS2data[3]; //store as one value for multiple functions
#endif
last_read = millis();
return ((PS2data[1] & 0xf0) == 0x70); // 1 = OK = analog mode - 0 = NOK
}
反复阅读代码，基本上可以搞清楚协议表了。之所以解读库函数，是为了更加清除了解协议的底层开发。
附上 论坛里的几篇文章：
PS2手柄通讯协议解析—附资料和源码
https://blog.csdn.net/weixin_44793491/article/details/105781595
arduino连接ps2手柄控制智能小车实践记录
https://blog.csdn.net/qq_30019617/article/details/109245402
arduino连接ps2手柄控制智能小车实践记录-续
https://blog.csdn.net/qq_30019617/article/details/109444260
扫一扫
1万+
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
