【动态规划进阶-背包型】钱币系统

【动态规划进阶-背包型】钱币系统

Time Limit:1000MS  Memory Limit:655360K
Total Submit:34 Accepted:16

Description

母牛们不但创建了它们自己的政府而且选择了建立了自己的货币系统。由于它们特殊的思考方式，它们对货币的数值感到好奇。
传统地，一个货币系统是由1,5,10,20 或 25,50, 和 100的单位面值组成的。
母牛想知道有多少种不同的方法来用货币系统中的货币来构造一个确定的数值。
举例来说, 使用一个货币系统 {1,2,5,10,...}产生 18单位面值的一些可能的方法是:18x1, 9x2, 8x2+2x1, 3x5+2+1,等等其它。写一个程序来计算有多少种方法用给定的货币系统来构造一定数量的面值。保证总数将会适合long long (C/C++) 和 Int64 (Free Pascal)，即在0 到2^63-1之间。

Input

货币系统中货币的种类数目是 V (1<=V<=25)。要构造的数量钱是 N (1<= N<=10,000)。
第一行: 二个整数，V 和 N 。
第二行： 可用的货币的面值 。

Output

单独的一行包含那个可能的用这v种硬币凑足n单位货币的方案数。

Sample Input

3 10
1 2 5

Sample Output

10

Hint

即为money问题

Source

USCAO

这不是一道很难的题，却让我纠结了很久。

一开始把 面值当作价值，张数当作体积。结果体积无限，如果这样就不是背包问题了。

然后把 面值当作体积，张数当作价值。还是想不出来，主要是不知道如何刚好到需要的面值

其实，求 不同方案总数 问题，就是把 多重背包 问题中的 MAX 改为 SUM。

赋初值  f[0]:=1;

对于“如何刚好到需要的面值”问题，只用输出 f[n] 就行了。

因为 f[i] 里存储着达到 i 的 不同方案总数。

标程： 

var m:array[1..25] of longint;
    v,n:integer;
procedure init;
  var i:integer;
  begin
    readln(v,n);
    for i:=1 to v do
      read(m[i]);
  end;
 
procedure work;
  var f:array[0..25,0..10000] of int64;
      i,j:integer;
  begin
    fillchar(f,sizeof(f),0);
    for i:=0 to v do
      f[i,0]:=1;
    for i:=1 to v do
      for j:=1 to n do
        if j-m[i]>=0 then f[i,j]:=f[i-1,j]+f[i,j-m[i]] else f[i,j]:=f[i-1,j];
    writeln(f[v,n]);
  end;
 
begin
  assign(input,'money.in');
  assign(output,'money.out');
  reset(input);
  rewrite(output);
  init;
  work;
  close(input);
  close(output);
end.

我的：

var
 i,j,v,n:longint;
 f:array[0..10000+1]of int64;
 w:array[1..25+1]of longint;

begin
 read(v,n);
 for i:=1 to v do read(w[i]);
 f[0]:=1;
 for i:=1 to v do
  for j:=w[i] to n do
   f[j]:=f[j]+f[j-w[i]];
  write(f[n]);
end.