PL/SQL中的参数 In ,Out, Nocopy

PL/SQL中对out，in out参数使用的？默认形参会复制一份实参的副本，然后在内部传递，修改等，发生异常，不会赋值给实参，控制权交还调用环境，而实参值不变，还是调用前的值。而使用了NOCOPY后，形参将获得一个指向实参的指针，然后在内部传递，赋值都直接修改实参了，此时如果异常发生，控制权交还调用环境，但是实参已经被修改了。无法还原成调用前的值。
对参数I N使用NOCOPY将会产生编译错误，这是因为参数I N总是按引用传递.
NOCOPY的主要优点是可以提高程序的效率。当我们传递大型PL/SQL表时，其优越性特别显著.使用NOCOPY的限制在某些情况下，NOCOPY将被编译器忽略，这时的参数仍将按值传递。这时，编译器不会报告编译错误。由于NOCOPY是一个提示项(Hint),编译器可以决定是否执行该项。在下列情况下，编译器将忽略NOCOPY项：
1.实参是索引表(index-by table)的成员时。如果该实参是全表，则该限制不起作用。
2.实参被强制指定精度，比例或NOT NULL时。该限制将不适用按最大长度强制的字符串参数。
3.实参和形参都是记录类型，二者是以隐含方式或使用了%ROWTYPE类型声明时，作用在对应字段的强制说明不一致。
4.传递实参需要隐式类型转换时。
5.子程序涉及到远程过程调用(PRC)。远程过程调用就是跨越数据库对远程服务器的过程调用。

例子：

DECLARE
l_1 NUMBER := 10;
l_2 NUMBER := 20;
l_3 NUMBER := 30;
PROCEDURE test_out(p1 IN NUMBER,
x1 IN OUT NUMBER,
x2 IN OUT NOCOPY NUMBER) IS
BEGIN
x1 := p1;
dbms_output.put_line('inside test_out, x1=' || x1);
x2 := p1;
dbms_output.put_line('inside test_out, x2=' || x2);
（--）raise_application_error(-20005, 'test NOCOPY');
END;
BEGIN
dbms_output.put_line('before, l_1=' || l_1 || ', l_2=' || l_2 ||
', l_3=' || l_3);
BEGIN
--the OUT parameter has no value at all until the program terminates successfully,
--unless you have requested use of the NOCOPY hint
test_out(l_1, l_2, l_3);
EXCEPTION
WHEN OTHERS THEN
dbms_output.put_line('SQLCODE => ' || SQLCODE || ', SQLERRM => ' ||
SQLERRM);
END;
dbms_output.put_line('after, l_1=' || l_1 || ', l_2=' || l_2 || ', l_3=' || l_3);
END;

如果不mark掉 raise_application_error，輸出結果：

before, l_1=10, l_2=20, l_3=30
inside test_out, x1=10
inside test_out, x2=10
SQLCODE => -20005, SQLERRM => ORA-20005: test NOCOPY
after, l_1=10, l_2=20, l_3=10

如果mark掉 raise_application_error，輸出結果：

before, l_1=10, l_2=20, l_3=30
inside test_out, x1=10
inside test_out, x2=10
after, l_1=10, l_2=10, l_3=10

得出結論：

out 參數在程序正常下，是要返回賦予其值，而出現錯誤時，則不作任何處理，即使在賦值之後，仍然還是原值。

out nocopy 則是在程序出現錯誤情況下，仍然返回賦值之後的值。